@echo off

setlocal

SET UPDATESTATUS=__svnup__%RANDOM%__

SET /A NB_TESTED=0
SET /A NB_GOOD=0

echo.
echo Gathering data...
svn st %* > %UPDATESTATUS%

echo.
echo ======================================
echo  New sourcefiles
echo ======================================
call:CheckNewSourceFiles py
call:CheckNewSourceFiles cpp
call:CheckNewSourceFiles c
call:CheckNewSourceFiles h
call:CheckNewSourceFiles bat
call:CheckNewSourceFiles php
call:CheckNewSourceFiles sql

call:DisplayResults


echo.
echo ======================================
echo  Modified sourcefiles
echo ======================================
call:CheckModifiedSourceFiles py
call:CheckModifiedSourceFiles cpp
call:CheckModifiedSourceFiles c
call:CheckModifiedSourceFiles h
call:CheckModifiedSourceFiles bat
call:CheckModifiedSourceFiles php
call:CheckModifiedSourceFiles sql

call:DisplayResults


echo.
echo ======================================
echo  Unversionned files
echo ======================================
call:CheckUnversionnedSourceFiles py
call:CheckUnversionnedSourceFiles cpp
call:CheckUnversionnedSourceFiles c
call:CheckUnversionnedSourceFiles h
call:CheckUnversionnedSourceFiles bat
call:CheckUnversionnedSourceFiles php
call:CheckUnversionnedSourceFiles sql

call:DisplayResults


echo.

del %UPDATESTATUS%


endlocal

goto:eof

:: =================================================
:: Displays a message if all the tests were
:: successful.
:: It also resets the counters
:: =================================================
:DisplayResults
if %NB_TESTED%==%NB_GOOD% echo (none found)

SET /A NB_TESTED=0
SET /A NB_GOOD=0
goto:eof

:: =================================================
:: This routine increments %NB_GOOD% if no new
:: files show up in the %UPDATESTATUS% file.
:: It always increment %NB_TESTED%.
:: =================================================
:CheckNewSourceFiles
findstr /r "^[A].*\.%~1$"  %UPDATESTATUS%
SET /A NB_TESTED=%NB_TESTED%+1  
SET /A NB_GOOD=%NB_GOOD%+%ERRORLEVEL%
goto:eof

:: =================================================
:: This routine increments %NB_GOOD% if no modified
:: files show up in the %UPDATESTATUS% file.
:: It always increment %NB_TESTED%.
:: =================================================
:CheckModifiedSourceFiles
findstr /r "^[M].*\.%~1$"  %UPDATESTATUS%
SET /A NB_TESTED=%NB_TESTED%+1  
SET /A NB_GOOD=%NB_GOOD%+%ERRORLEVEL%
goto:eof

:: =================================================
:: This routine increments %NB_GOOD% if no unversionned
:: files show up in the %UPDATESTATUS% file.
:: It always increment %NB_TESTED%.
:: =================================================
:CheckUnversionnedSourceFiles
findstr /r "^[\?].*\.%~1$"  %UPDATESTATUS%
SET /A NB_TESTED=%NB_TESTED%+1  
SET /A NB_GOOD=%NB_GOOD%+%ERRORLEVEL%
goto:eof